ALIG

%%HP: T(3)A(D)F(.);
{ TC2 MRK2 TC1 MRK1
ST2GEO ST1GEO }

TC2

%%HP: T(3)A(D)F(.);
\<< TCOR LAM ELSC *
'LAM2' STO THA AZSC
* 'THA2' STO LAM2
THA2 VEC 'SML2' STO
SML2 SML1 CROSS
'SML3' STO SML1
OBJ\-> DROP SML2 OBJ\->
DROP SML3 OBJ\-> DROP
{ 3 3 } \->ARRY TRN
'V2' STO V2 V1 *
'TMX' STO
\>>

MRK2
%%HP: T(3)A(D)F(.);
\<< RA2 H 'H2' STO
DE2 HMS\-> H2 VEC
'L2' STO L2 L1
CROSS 'L3' STO L1
OBJ\-> DROP L2 OBJ\->
DROP L3 OBJ\-> DROP {
3 3 } \->ARRY TRN INV
'V1' STO
\>>

TC1

%%HP: T(3)A(D)F(.);
\<< TCOR LAM ELSC *
'LAM1' STO THA AZSC
* 'THA1' STO LAM1
THA1 VEC 'SML1' STO
\>>

MRK1

%%HP: T(3)A(D)F(.);
\<< RA1 H 'H1' STO
DE1 HMS\-> H1 VEC
'L1' STO
\>>

ST2GEO

%%HP: T(3)A(D)F(.);
\<< CORD RA 'RA2' STO
DE 'DE2' STO
\>>

ST1GEO

%%HP: T(3)A(D)F(.);
\<< CORD RA 'RA1' STO
DE 'DE1' STO
\>>

TCOR

%%HP: T(3)A(D)F(.);
\<< "\Gh\|^\Gl" PROMPT HMS\->
'LAM' STO HMS\->
'THA' STO
\>>

CORD

%%HP: T(3)A(D)F(.);
\<< "\Ga\|^\Gd" PROMPT 'DE'
STO 'RA' STO
\>>

CST

%%HP: T(3)A(D)F(.);
{ CORD EL AZ TDE
TRA TC }

VIEW

%%HP: T(3)A(D)F(.);
{ CORD EL AZ TDE
TRA TC }

TC

%%HP: T(3)A(D)F(.);
\<< RA VWDT HMS- H
DEd SWAP VEC 'BARY'
STO TMX BARY *
'AARY' STO AARY V\->
ASIN ELSC / \->HMS
'LAM' STO 'TP' STO
'BM' STO TP BM ATN2
AZSC / ANG + \->HMS
'THA' STO THA LAM
\>>

EL
%%HP: T(3)A(D)F(.);
\<< DEd SIN LAT HMS\->
SIN * DEd COS LAT
HMS\-> COS * RA H COS
* + ASIN
\>>

AZ

%%HP: T(3)A(D)F(.);
\<< DEd SIN EL LAT \->
SD A TH '(SD-SIN(TH
)*SIN(A))/(COS(TH)*
COS(A))' ACOS RA H
SIN \-> SH
  \<<
    IF 'SH\>=0'
    THEN 360 - NEG
    END
  \>>
\>>

H

%%HP: T(3)A(D)F(.);
\<< 'TRA' STO LST
HMS\-> TRA HMS\-> -
HNRM 15 *
\>>

LST

%%HP: T(3)A(D)F(.);
\<< GST HMS\-> LON HMS\->
15 / - HNRM \->HMS
\>>

GST

%%HP: T(3)A(D)F(.);
\<< JDZ DROP JD0
J2000 - 36525 / \-> T
'6.697374558+
2400.051336*T+
.000025862*T*T'
HNRM 'T0' STO UTD
1.002737909 * 24 *
T0 + HNRM \->HMS 4
FIX
\>>

JDZ

%%HP: T(3)A(D)F(.);
\<< 1.012 DATE DDAYS
J2000 + .5 - UTD IP
+ 'JD0' STO JD0 UTD
FP +
\>>

VEC

%%HP: T(3)A(D)F(.);
\<< 'TRA' STO 'TDE'
STO TDE COS TRA COS
* TDE COS TRA SIN *
TDE SIN 3 \->ARRY
\>>

